4D-jp 4D Japan Technical Support Team

埋込Webレンダリングエンジンのバージョン情報


埋込Webレンダリングエンジンのバージョン情報を表示するためのメソッドサンプルを紹介します。

このメソッドを実行しますと、4Dで利用している埋込Webレンダリングエンジンのバージョンが表示されます。 JavaScriptを実行するようなとき参考にして、プログラミングを的確に行うことができます。

Case of 
	: (FORM Event=Null)
		
		//ページを組み立てる
		$page:=New object  //フォームのページデザインをセットするオブジェクト変数
		$page.objects:=New object
		$page.objects["Web Area"]:=New object(\
		"type"; "webArea"; \
		"left"; 0; "top"; 0; "width"; 700; "height"; 450; \
		"sizingY"; "grow"; "sizingX"; "grow"; \
		"webEngine"; "embedded"; \
		"method"; Current method name; \
		"events"; New collection("onLoad"))
		//フォームを組み立てる
		$dynForm:=New object("rightMargin"; 0; "bottomMargin"; 0)
		$dynForm.pages:=New collection(New object; $page)
		
		//ダイアログの表示
		SET MENU BAR(1)
		$ref:=Open form window($dynForm; *)
		DIALOG($dynForm)
		
	: (Form event code=On Load)
		
		//外部リンクをフィルタリングする
		ARRAY TEXT($url; 0)
		ARRAY BOOLEAN($filter; 0)
		APPEND TO ARRAY($url; "*.*")
		APPEND TO ARRAY($filter; False)
		WA SET URL FILTERS(*; "Web Area"; $url; $filter)
		//情報を表示
		WA OPEN URL(*; "Web Area"; "chrome://version/")
		
End case